Skip to main content

 ST7735 LCD With Arduino Uno and Arduiono Nano

(TUTORIAL)









Hi. Today we learn about 1.8 inch ST7735 LCD TFT color display. We will use here Arduino uno and Arduino nano for this tutorial. it will be pretty cool . let us start .

 


The ST7735 TFT display is a 1.8″ display with a resolution of 128×160 pixels and can display a wide range of colors (full 18-bit color, 262,144 shades!). The display uses the SPI protocol for communication and has its own pixel-addressable frame buffer which means it can be used with all kinds of micro controller and you only need 4 I.O. pins. To complement the display, It also comes with an SD card slot on which colored bit maps can be loaded and easily displayed on the screen.

Features of ST7735 TFT---

·         1.8″ diagonal LCD TFT display

·      ·         128×160 resolution, 18-bit (262,144) color

·      ·         4 or 5 wire SPI digital interface

·      ·        Built-in microSD slot – uses 2 more digital lines

·     ·         5V compatible! Use with 3.3V or 5V logic

·      ·       Onboard 3.3V @ 150mA LDO regulator

·      ·        2 white LED backlight, a transistor connected so you can PW dim             the back light.

·       ·        1×10 header for easy bread boarding

·      ·       4 x 0.9″/2mm mounting holes in corners

·       ·      Overall dimensions: 1.35″ x 2.2″ x 0.25″ (34mm x 56mm x 6.5mm)

·       ·       Current draw is based on LED back light usage: with full back light        draw is ~50mA


This tutorial is to demonstrate the abilities of the TFT to display images and text in different colors and animation.

 NEEDED PARTS- 

1- ST7735. TFT Display.
2-Arduino Uno.
3-Arduino Nano.
4- Some Jumper wire .
5- Data cable .
6-Pc with Arduino IDE.

Libraries -

Open Arduino IDE-Go Tools Click Manege Library then download all given library.( from search one by one and download )

1- Adafruit GFX .
2- Adafruit_ST7735 
3- TFT







Arrange all parts and connect as per schematics .

(ST7735 Display with arduino Uno)

(ST7735 Display with Arduino NANO)

ST7735 Display connections with Arduino.

LED - 3.3v

SCK - D13

SDA - D11

DC - D9

Reset - D8

CS - D10

GND - GND

VCC - 5v

For more information Watch it.








Code-For code-
Open Arduino IDE - Go to Example  Adafruit ST 7735 and open graphic test or go to TFT and you can use all files like TFT color Picker, TFT display text and TFT Graph. But you have to change in -

 #define TFT_CS        10
 #define TFT_RST        8 
 #define TFT_DC         9

Because we are using same things in our schematic .
 
OR Copy and pest the given code.


#include <Adafruit_GFX.h>    // Core graphics library

#include <Adafruit_ST7735.h> // Hardware-specific library for ST7735
#include <Adafruit_ST7789.h> // Hardware-specific library for ST7789
#include <SPI.h>

#if defined(ARDUINO_FEATHER_ESP32) // Feather Huzzah32
  #define TFT_CS         14
  #define TFT_RST        15
  #define TFT_DC         32

#elif defined(ESP8266)
  #define TFT_CS         4
  #define TFT_RST        16                                            
  #define TFT_DC         5

#else
  // For the breakout board, you can use any 2 or 3 pins.
  // These pins will also work for the 1.8" TFT shield.
  #define TFT_CS        10
  #define TFT_RST        8 // Or set to -1 and connect to Arduino RESET pin
  #define TFT_DC         9
#endif

// OPTION 1 (recommended) is to use the HARDWARE SPI pins, which are unique
// to each board and not reassignable. For Arduino Uno: MOSI = pin 11 and
// SCLK = pin 13. This is the fastest mode of operation and is required if
// using the breakout board's microSD card.

// For 1.44" and 1.8" TFT with ST7735 use:
Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS, TFT_DC, TFT_RST);

// For 1.14", 1.3", 1.54", 1.69", and 2.0" TFT with ST7789:
//Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_RST);


// OPTION 2 lets you interface the display using ANY TWO or THREE PINS,
// tradeoff being that performance is not as fast as hardware SPI above.
//#define TFT_MOSI 11  // Data out
//#define TFT_SCLK 13  // Clock out

// For ST7735-based displays, we will use this call
//Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCLK, TFT_RST);

// OR for the ST7789-based displays, we will use this call
//Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCLK, TFT_RST);


float p = 3.1415926;

void setup(void) {
  Serial.begin(9600);
  Serial.print(F("Hello! ST77xx TFT Test"));

  // Use this initializer if using a 1.8" TFT screen:
  tft.initR(INITR_BLACKTAB);      // Init ST7735S chip, black tab

  // OR use this initializer if using a 1.8" TFT screen with offset such as WaveShare:
  // tft.initR(INITR_GREENTAB);      // Init ST7735S chip, green tab

  // OR use this initializer (uncomment) if using a 1.44" TFT:
  //tft.initR(INITR_144GREENTAB); // Init ST7735R chip, green tab

  // OR use this initializer (uncomment) if using a 0.96" 160x80 TFT:
  //tft.initR(INITR_MINI160x80);  // Init ST7735S mini display

  // OR use this initializer (uncomment) if using a 1.3" or 1.54" 240x240 TFT:
  //tft.init(240, 240);           // Init ST7789 240x240

  // OR use this initializer (uncomment) if using a 1.69" 280x240 TFT:
  //tft.init(240, 280);           // Init ST7789 280x240

  // OR use this initializer (uncomment) if using a 2.0" 320x240 TFT:
  //tft.init(240, 320);           // Init ST7789 320x240

  // OR use this initializer (uncomment) if using a 1.14" 240x135 TFT:
  //tft.init(135, 240);           // Init ST7789 240x135
  
  // OR use this initializer (uncomment) if using a 1.47" 172x320 TFT:
  //tft.init(172, 320);           // Init ST7789 172x320

  // SPI speed defaults to SPI_DEFAULT_FREQ defined in the library, you can override it here
  // Note that speed allowable depends on chip and quality of wiring, if you go too fast, you
  // may end up with a black screen some times, or all the time.
  //tft.setSPISpeed(40000000);

  Serial.println(F("Initialized"));

  uint16_t time = millis();
  tft.fillScreen(ST77XX_BLACK);
  time = millis() - time;

  Serial.println(time, DEC);
  delay(500);

  // large block of text
  tft.fillScreen(ST77XX_BLACK);
  testdrawtext("Lorem ipsum dolor sit amet, consectetur adipiscing elit. Curabitur adipiscing ante sed nibh tincidunt feugiat. Maecenas enim massa, fringilla sed malesuada et, malesuada sit amet turpis. Sed porttitor neque ut ante pretium vitae malesuada nunc bibendum. Nullam aliquet ultrices massa eu hendrerit. Ut sed nisi lorem. In vestibulum purus a tortor imperdiet posuere. ", ST77XX_WHITE);
  delay(1000);

  // tft print function!
  tftPrintTest();
  delay(4000);

  // a single pixel
  tft.drawPixel(tft.width()/2, tft.height()/2, ST77XX_GREEN);
  delay(500);

  // line draw test
  testlines(ST77XX_YELLOW);
  delay(500);

  // optimized lines
  testfastlines(ST77XX_RED, ST77XX_BLUE);
  delay(500);

  testdrawrects(ST77XX_GREEN);
  delay(500);

  testfillrects(ST77XX_YELLOW, ST77XX_MAGENTA);
  delay(500);

  tft.fillScreen(ST77XX_BLACK);
  testfillcircles(10, ST77XX_BLUE);
  testdrawcircles(10, ST77XX_WHITE);
  delay(500);

  testroundrects();
  delay(500);

  testtriangles();
  delay(500);

  mediabuttons();
  delay(500);

  Serial.println("done");
  delay(1000);
}

void loop() {
  tft.invertDisplay(true);
  delay(500);
  tft.invertDisplay(false);
  delay(500);
}

void testlines(uint16_t color) {
  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x=0; x < tft.width(); x+=6) {
    tft.drawLine(0, 0, x, tft.height()-1, color);
    delay(0);
  }
  for (int16_t y=0; y < tft.height(); y+=6) {
    tft.drawLine(0, 0, tft.width()-1, y, color);
    delay(0);
  }

  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x=0; x < tft.width(); x+=6) {
    tft.drawLine(tft.width()-1, 0, x, tft.height()-1, color);
    delay(0);
  }
  for (int16_t y=0; y < tft.height(); y+=6) {
    tft.drawLine(tft.width()-1, 0, 0, y, color);
    delay(0);
  }

  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x=0; x < tft.width(); x+=6) {
    tft.drawLine(0, tft.height()-1, x, 0, color);
    delay(0);
  }
  for (int16_t y=0; y < tft.height(); y+=6) {
    tft.drawLine(0, tft.height()-1, tft.width()-1, y, color);
    delay(0);
  }

  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x=0; x < tft.width(); x+=6) {
    tft.drawLine(tft.width()-1, tft.height()-1, x, 0, color);
    delay(0);
  }
  for (int16_t y=0; y < tft.height(); y+=6) {
    tft.drawLine(tft.width()-1, tft.height()-1, 0, y, color);
    delay(0);
  }
}

void testdrawtext(char *text, uint16_t color) {
  tft.setCursor(0, 0);
  tft.setTextColor(color);
  tft.setTextWrap(true);
  tft.print(text);
}

void testfastlines(uint16_t color1, uint16_t color2) {
  tft.fillScreen(ST77XX_BLACK);
  for (int16_t y=0; y < tft.height(); y+=5) {
    tft.drawFastHLine(0, y, tft.width(), color1);
  }
  for (int16_t x=0; x < tft.width(); x+=5) {
    tft.drawFastVLine(x, 0, tft.height(), color2);
  }
}

void testdrawrects(uint16_t color) {
  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x=0; x < tft.width(); x+=6) {
    tft.drawRect(tft.width()/2 -x/2, tft.height()/2 -x/2 , x, x, color);
  }
}

void testfillrects(uint16_t color1, uint16_t color2) {
  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x=tft.width()-1; x > 6; x-=6) {
    tft.fillRect(tft.width()/2 -x/2, tft.height()/2 -x/2 , x, x, color1);
    tft.drawRect(tft.width()/2 -x/2, tft.height()/2 -x/2 , x, x, color2);
  }
}

void testfillcircles(uint8_t radius, uint16_t color) {
  for (int16_t x=radius; x < tft.width(); x+=radius*2) {
    for (int16_t y=radius; y < tft.height(); y+=radius*2) {
      tft.fillCircle(x, y, radius, color);
    }
  }
}

void testdrawcircles(uint8_t radius, uint16_t color) {
  for (int16_t x=0; x < tft.width()+radius; x+=radius*2) {
    for (int16_t y=0; y < tft.height()+radius; y+=radius*2) {
      tft.drawCircle(x, y, radius, color);
    }
  }
}

void testtriangles() {
  tft.fillScreen(ST77XX_BLACK);
  uint16_t color = 0xF800;
  int t;
  int w = tft.width()/2;
  int x = tft.height()-1;
  int y = 0;
  int z = tft.width();
  for(t = 0 ; t <= 15; t++) {
    tft.drawTriangle(w, y, y, x, z, x, color);
    x-=4;
    y+=4;
    z-=4;
    color+=100;
  }
}

void testroundrects() {
  tft.fillScreen(ST77XX_BLACK);
  uint16_t color = 100;
  int i;
  int t;
  for(t = 0 ; t <= 4; t+=1) {
    int x = 0;
    int y = 0;
    int w = tft.width()-2;
    int h = tft.height()-2;
    for(i = 0 ; i <= 16; i+=1) {
      tft.drawRoundRect(x, y, w, h, 5, color);
      x+=2;
      y+=3;
      w-=4;
      h-=6;
      color+=1100;
    }
    color+=100;
  }
}

void tftPrintTest() {
  tft.setTextWrap(false);
  tft.fillScreen(ST77XX_BLACK);
  tft.setCursor(0, 30);
  tft.setTextColor(ST77XX_RED);
  tft.setTextSize(1);
  tft.println("Hello World!");
  tft.setTextColor(ST77XX_YELLOW);
  tft.setTextSize(2);
  tft.println("Hello World!");
  tft.setTextColor(ST77XX_GREEN);
  tft.setTextSize(3);
  tft.println("Hello World!");
  tft.setTextColor(ST77XX_BLUE);
  tft.setTextSize(4);
  tft.print(1234.567);
  delay(1500);
  tft.setCursor(0, 0);
  tft.fillScreen(ST77XX_BLACK);
  tft.setTextColor(ST77XX_WHITE);
  tft.setTextSize(0);
  tft.println("Hello World!");
  tft.setTextSize(1);
  tft.setTextColor(ST77XX_GREEN);
  tft.print(p, 6);
  tft.println(" Want pi?");
  tft.println(" ");
  tft.print(8675309, HEX); // print 8,675,309 out in HEX!
  tft.println(" Print HEX!");
  tft.println(" ");
  tft.setTextColor(ST77XX_WHITE);
  tft.println("Sketch has been");
  tft.println("running for: ");
  tft.setTextColor(ST77XX_MAGENTA);
  tft.print(millis() / 1000);
  tft.setTextColor(ST77XX_WHITE);
  tft.print(" seconds.");
}

void mediabuttons() {
  // play
  tft.fillScreen(ST77XX_BLACK);
  tft.fillRoundRect(25, 10, 78, 60, 8, ST77XX_WHITE);
  tft.fillTriangle(42, 20, 42, 60, 90, 40, ST77XX_RED);
  delay(500);
  // pause
  tft.fillRoundRect(25, 90, 78, 60, 8, ST77XX_WHITE);
  tft.fillRoundRect(39, 98, 20, 45, 5, ST77XX_GREEN);
  tft.fillRoundRect(69, 98, 20, 45, 5, ST77XX_GREEN);
  delay(500);
  // play color
  tft.fillTriangle(42, 20, 42, 60, 90, 40, ST77XX_BLUE);
  delay(50);
  // pause color
  tft.fillRoundRect(39, 98, 20, 45, 5, ST77XX_RED);
  tft.fillRoundRect(69, 98, 20, 45, 5, ST77XX_RED);
  // play color
  tft.fillTriangle(42, 20, 42, 60, 90, 40, ST77XX_GREEN);
}






Labels:

Comments

Post a Comment

Popular posts from this blog

HOW WE CAN MAKE CNC PLOTTER FROM OLD DVD DRIVES WITH ARDUINO SHIELD IN HOME

Here we are sh owing you how we can make CNC PLOTTER from old dvd drives and Arduino uno with l293 driver shield.We can plot any image or any words with this.So try to make it and enjoy with plotter.Keep watching we will give you idea for more types of plotters.Also you can learn ,How you can make G code for plotter.
Post a Comment
Read more

TASMOTA WITH ESP

WHAT IS TASMOTA HOW WE CAN USE WITH ESP    DEVICES
Post a Comment
Read more

SMART-HOME AUTOMATION WITH ESP01 /ESP8266 (TASMOTA FIRMWARE)

                                   SMART-HOME AUTOMATION                          { ESP-01 WITH TASMOTA FIRMWARE } TODAY WE ARE MAKING HERE A HOME AUTOMATION DEVICE WITH TASMOTA FIRMWARE . YOU CAN CONTROL HOME APPLIANCES WITH YOUR MOBILE OR PC SCREEN WITH WI FI .     # VERY CHEAP . # VERY EASY.     # NO CODE REQUIRED. REQUIREMENTS   ( HARDWARE ) •      ESP 01 (8266) MODULE •      ESP 01 MODULE PROGRAMMER OR ARDUINO UNO. •      JUMPER WIRES. •      OPTIONAL PUSH BUTTON •      LATEST VERSION OF TASMOTA. •      TASMOTIZER . •      PC AND DATA CABLE  ( IF YOU ARE USING ARDUINO UNO FOR FLASHING ). •      3.7 VOLT DC POWER SUPPLY. ( AMS 1117-3.3 LDO ) •     LM7805    IC FOR RELAY MODULE . •     BATTERY 7.2 VOLT. •     PC- FOR PROGRAMMING                                                     REQUIREMENTS                       (SOFTWARE)                •     DOWNLOAD LATEST VERSION OF TASMOTA BINARY FILE  .( LINK                          GIVEN )              http://ota.tasm
Post a Comment
Read more

Smart Robot with voice control, line follower, obstacle avoiding and remote control.

SMART ROBOT CAR  This smart robo is based on arduino , and canwork in 3 modes .... all these modes are  selected by a common android app 1st  mode  : Inbuilt  App  Joystick    working via the app inbuilt joystick command were we can use joystick to control   robo like a    RC car.          2nd mode : Voice controlled robo      Here you can give input to the robo with voice commands. 3rd mode : Autonomous mode      Here the robo will use its ultrasonic sensor to find free way and avoid collision  with objects or      wall. 4th mode : Line follower (optional).      Here we are giving you the option of line following if you need you can active.   5th mode ; IR remote control (optional). This option is also available here.if you need you may active.  ____________________________________________________________________ Download link for app => ------------------------------------------------------------------------------------------------------ Spare parts (needed)               => 1-
Post a Comment
Read more

Home Automation With Arduino .(Bluetooth)

Here we are showing you that how you can run any home appliances with smartphones,This is the projects model of a arduino bluetooth device .you can control your's home appliances with any smart phone from anywhere with internet .Here we are using a electric 220 volts AC bulb,to show you .You can use it for your all other home appliances like fans ,air conditioner,lights and many more. to run with relays with smart way.So learn that and make your home Smart Home.   Download link here   (for sketch ) Download link here    ( for Smartphone ) If you have any inquiry please whatsapp on 00966571482173 or mail on geniustec18@gmail.com  Thanks for watching. 
Post a Comment
Read more

controling devices with Smart phone and Arduino

Today we will show you a project that  can control devices with smart phones. We can increase or decrease the speed of fan, Desert coolers, Air conditioner  or increase or decrease the lights of lamp. we can make smart home with  Arduino. we can control devices anywhere in the world with internet .Here we will use arduino uno and bluetooth for controlling the devices. Contact us for any inquiry on mail    geniustec18@Gmail.com Download link  {For Arduino Uno } Download link   { APK file for Your Smartphone }
Post a Comment
Read more